6. Vaja

Implicitno podane krivulje

Nekatere slike krivulj smo do sedaj že spoznali, ko smo risali grafe funkcij y=f(x). Te krivulje so bile v ravnini podane eksplicitno, poznamo pa tudi krivulje, katerih predpis je podan implicitno (ne moremo izraziti y). Te krivulje rišemo z ukazom ContourPlot.

1.a) Parabole v ravnini so podane z enačbami (y^2)=2px, kjer je p polparameter parabole. Z ukazom ContourPlot nariši parabolo (y^2)=2x.

ContourPlot[y^2==2x,{x,-1,4},{y,-3,3},Axes->True]

Z ukazom Manipulate lahko interaktivno izbiramo polparameter p dane parabole.

Manipulate[ContourPlot[y^2==2*p*x,{x,-1,4},{y,-3,3},Axes->True],{{p,1,"Polparameter p"},0,1}]

1.b) Hiperbole v ravnini so podane z enačbami ((x^2)/(a^2))-((y^2)/(b^2))=1, kjer je a glavna polos hiperbole in b stranska polos hiperbole.

Manipulate[ContourPlot[x^2/a^2-y^2/b^2==1,{x,-10,10},{y,-10,10},Axes->True],{{a,1,"Glavna polos a"},0,1},{{b,1,"Stranska polos b"},0,1}]

Parametrično podane krivulje

Parametrična krivulja je slika vektorske funkcije ene spremenljivke (ki jo ponavadi označimo s t kot 'time'=čas) in ima dve ali tri komponente. Te krivulje rišemo z ukazom ParametricPlot.

2.a) Elipsa s polosema a in b ima parametrično obliko x(t)=acos(t),y(t)=bsin(t). Nariši elipso s polosema a=2 in b=1 z ukazom ParametricPlot.

ParametricPlot[{2Cos[t],Sin[t]},{t,0,2Pi}]

Parametrično podano krivuljo si pogosto predstavljamo kot gibanje točko po ravnini ali v prostoru.

Manipulate[Animate[Graphics[{RGBColor[1,0,0],Line[Table[{a Cos[t],b Sin[t]},{t,0,2Pi,Pi/50}]],RGBColor[0,0,0],PointSize[0.03],Point[{a Cos[T],b Sin[T]}],RGBColor[0,0,1],If[hitrost,Table[{Arrow[{{a Cos[k Pi/10],b Sin[k Pi/10]},{a Cos[k Pi/10]-1/4 a Sin[k Pi/10],b Sin[k Pi/10]+1/4 b Cos[k Pi /10]}}]},{k,20}],{}]},ImageSize->{512,384}],{{T,0,"Vrednost parametra t"},0,2π},AnimationRunning->False],{{a,2,"Velikost polosi x"},Table[j,{j,1,3}]},{{b,1,"Velikost polosi y"},Table[k,{k,1,3}]},{{hitrost,False,"Prikaži vektorje hitrosti"},{True,False}}]

2.b) Epicikloida je krivulja, ki jo opiše točka krožnice, ki se kotali po drugi krožnici zunaj nje. Njena parametrična enačba je x=(R+r)cos(t)-rcos(((R+r)/r)t), y=(R+r)sin(t)-rsin(((R+r)/r)t), kjer so R=polmer mirujoče krožnice, r=polmer kotaleče krožnice in t=polarni kot. Nariši epicikloido za primera R=1 in r=(1/4),1!

R=1

r=1/4

ParametricPlot[{(R+r)Cos[t]-r Cos[(R+r)t/r],(R+r)Sin[t]-r Sin[(R+r)t/r]},{t,0,2Pi}]

r=1

ParametricPlot[{(R+r)Cos[t]-r Cos[(R+r)t/r],(R+r)Sin[t]-r Sin[(R+r)t/r]},{t,0,2Pi}]

Poglejmo si še pridružene animacije za R=1 in nekatera razmerja (r/R).

Manipulate[Animate[Graphics[{Thickness[0.003],PointSize[0.013],RGBColor[1,0,0],Circle[{0,0},1],RGBColor[0,0,1],Line[Table[{(1+r)Cos[t]-r Cos[(1+r)t/r],(1+r)Sin[t]-r Sin[(1+r)t/r]},{t,0,2Pi,Pi/50}]],
RGBColor[0,0.8,0],Rotate[{Translate[
{Circle[{0,0},r],
RGBColor[0,0,0],Point[{-r,0}]},(1+r){Cos[θ],Sin[θ]}]},
θ(1+(1/r)),(1+r){Cos[θ],Sin[θ]}]},{},PlotRange->{{-(1+2*r),1+2*r},{-(1+2*r),1+2*r}},ImageSize->{500,375}],
{{θ,0,"Vrednost parametra t"},0,2π},AnimationRunning->False],
{{r,1/4,"Razmerje polmerov"},Table[1/j,{j,1,4}]}]

2.c)Izračunaj ploščino lika, ki ga oklepata zgornji krivulji.

x[t_]:=(R+r)Cos[t]-r Cos[(R+r)t/r]

y[t_]:=(R+r)Sin[t]-r Sin[(R+r)t/r]

r=1/4

ParametricPlot[{a((R+r)Cos[t]-r Cos[(R+r)t/r]),a((R+r)Sin[t]-r Sin[(R+r)t/r])},{a,0,1},{t,0,2Pi}]

1/2Integrate[x[t]y'[t]-x'[t]y[t],{t,0,2Pi}]

r=1

ParametricPlot[{a((R+r)Cos[t]-r Cos[(R+r)t/r]),a((R+r)Sin[t]-r Sin[(R+r)t/r])},{a,0,1},{t,0,2Pi}]

1/2Integrate[x[t]y'[t]-x'[t]y[t],{t,0,2Pi}]

2.d) Nariši vijačnico r(t)=( cos(t), sin(t), (t/(2π)))  za vrednosti t med -4π in 4π s pomočjo ukaza  ParametricPlot3D.

Clear[r]

r[t_]:={Cos[t],Sin[t],t/(2Pi)}

krivulja=ParametricPlot3D[r[t],{t,-4Pi,4Pi}]

2.e) Izračunaj dolžino enega zavoja vijačnice.

Integrate[Sqrt[r'[t].r'[t]],{t,0,2Pi}]

Krivulje v polarnih koordinatah

Doslej smo krivulje podajali le v kartezičnih korrdinatah (x,y), sedaj pa bomo predstavili tudi polarne koordinate (r,φ), kjer je r oddaljenost točke od izhodišča, φ pa kot, ki ga oklepata pozitivni del osi x in daljica, ki povezuje točko z izhodiščem. Za prehod med polarnimi in kartezičnimi koordinatami veljata zvezi:
x = r cos(φ)	r =(Sqrt[(x^2)+(y^2)])
y = r sin(φ) 	φ = arctg((y/x))

Krivulje v polarnih koordinatah, ki so podane z zvezo r = f(φ), za α≤φ≤β, rišemo z ukazom PolarPlot.

3.a) Stožnice s koordinatnim izhodiščem v gorišču lahko podamo tudi v polarni obliki  r(ϕ)=p/(1+ϵcos(ϕ))  za 0≤φ≤2π.

Manipulate[PolarPlot[p/(1+e Cos[t]),{t,0,2Pi},PlotRange->5],{{e,0,"Ekscentričnost stožnice e"},0,2},{{p,1,"Parameter p"},0,2}]

3.b) Izračunaj ploščino elipse r(ϕ)=1/(1+0.5cos(ϕ)).

ParametricPlot[{r 1/(1+0.5 Cos[t]) Cos[t],r 1/(1+0.5 Cos[t])Sin[t]},{t,0,2Pi},{r,0,1}]

S=1/2Integrate[(1/(1+1/2 Cos[t]))^2,{t,0,2Pi}]

Grafi funkcij dveh spremenljivk

Sedaj se bomo ukvarjali s funkcijami dveh spremenljivk, ki so podane s predpisom f(x,y); a≤x≤b, c≤y≤d. Grafi teh funkcij so ploskve v prostoru in jih lahko učinkovito predstavimo s funkcijo Plot3D

4. a) Nariši grafa funkcij f(x,y)=sin(x)+y in f(x,y)=(y^2).

Plot3D[Sin[x]+y,{x,-4Pi,4Pi},{y,-5,5}]

Plot3D[y^2,{x,-5,5},{y,-3,3}]

4. b) Nariši stožec, ki je podan z enačbo z = (Sqrt[(x^2)+(y^2)])in paraboloid, ki je podan z enačbo z=(x^2)+(y^2).

Plot3D[Sqrt[x^2+y^2],{x,-3,3},{y,-3,3}]

Plot3D[x^2+y^2,{x,-3,3},{y,-3,3}]

Slike nekaterih ploskev (predvsem tistih, ki so sestavljene iz krožnic) lepše narišemo z ukazom ParametricPlot3D.

4. c) Nariši stožec in paraboloid še v parametrični obliki.

ParametricPlot3D[{r Cos[t],r Sin[t], r},{t,0,2Pi},{r,0,2}]

ParametricPlot3D[{r Cos[t],r Sin[t], r^2},{t,0,2Pi},{r,0,2}]

Pogosto nas zanimajo nivojnice neke funkcije. To so krivuje, ki jih dobimo, če graf funkcije presekamo z ravnino z=a, za neko vrednost a∈R.

4. d) Poišči nivojnice paraboloida f(x,y)=(x^2)+ (y^2) in pa funkcije f(x,y)=(y^2) z ukazom ContourPlot.

ContourPlot[x^2+ y^2,{x,-3,3},{y,-3,3},Contours->{0,1/5,1/4,1/3,1/2,1,2,3,4,5,6,7,8}]

ContourPlot[y^2,{x,-2,2},{y,-2,2},Contours->{0,1/4,1/3,1/2,1,3/2,2,5/2,3,7/2,4}]

Ekstremi funkcij dveh spremenljivk

Pri funkcijah dveh spremenljivk obravnavamo parcialna odvoda, ki ju izračunamo z ukazoma D[f[x,y],x] in  D[f[x,y],y].

5. a) Za funkcijo f(x,y)=(x^2) izračunaj parcialna odvoda ((∂ f)/(∂ x)) in ((∂ f)/(∂ y)).

Clear[f]

f[x_,y_]:= x^2

Plot3D[f[x,y],{x,-3,3},{y,-3,3}]

D[f[x,y],x]
D[f[x,y],y]

5. b) Poišči enačbo tangentne ravnine na graf funkcije f v točki T(1,2) in jo nariši na isto sliko skupaj s funkcijo.

TangentnaRavnina[f_,a_,b_,x_,y_]:=f[a,b]+(D[f[x,y],x]/.{x->a,y->b})(x-a)+(D[f[x,y],y]/.{x->a,y->b})(y-b)

TangentnaRavnina[f,1,2,x,y]

Plot3D[{f[x,y],1+2(-1+x)},{x,-3,3},{y,-3,3}]

S parcialnimi odvodi funkcije pa tudi iščemo kandidate za stacionarne točke, to so točke, kjer sta oba parcialna odvoda enaka nič. Tangentna ravnina je v teh točkah vzporedna x-y ravnini.

5. c) Poišči stacionarne točke funkcije f(x,y)=(x^2)+(y^2).

Clear[f]

f[x_,y_]:=x ^2+y^2+1

Solve[{D[f[x,y],x]==0,D[f[x,y],y]==0},{x,y}]

TangentnaRavnina[f,0,0,x,y]

Plot3D[{f[x,y],1},{x,-3,3},{y,-3,3}]

Globalne ekstreme funkcij dveh spremenljivk iščemo z ukazoma  Minimize in Maximize.

5. d) Poišči globalni minimum in globalni maksimum funkcije f(x,y)=5(x^2)-3xy+4(y^2)+3x na kvadratu z oglišči A(-1,-1), B(1,-1), C(1,1) in D(-1,1).

Clear[f]

f[x_,y_]:=5x^2-3x y+4y^2+3x

Plot3D[f[x,y],{x,-1,1},{y,-1,1}]

Maximize[{f[x,y],-1≤x≤1,-1≤y≤1},{x,y}]

Minimize[{f[x,y],-1≤x≤1,-1≤y≤1},{x,y}]

Integrali funkcij dveh spremenljivk

6.a) Integriraj funkcijo f(x)=2-(x^2)-(y^2) po pravokotniku -1≤x≤1, -1≤y≤1.

RegionPlot3D[2-x^2+-y^2>z,{x,-1,1},{y,-1,1},{z,0,2}]

Integrate[Integrate[2-x^2-y^2,{x,-1,1}],{y,-1,1}]

6.b) Integriraj funkcijo f (x) =1-x-y  po trikotniku omejenem s premico y =1- x in pa x ter y osjo.

Plot3D[1-x-y,{x,0,1},{y,0,1},AxesOrigin->{0,0,0}]

RegionPlot3D[1-x-y>z&&y≤1-x&&y>0&&x>0,{x,0,1},{y,0,1},{z,0,1}]

Integrate[Integrate[1-x-y,{y,0,1-x}],{x,0,1}]

Naloge

1.a) Nariši parametrično podano krivuljo r(t)=((t^2),t-(t^3)) za t∈[-2,2].
b) Izračunaj ploščino lika, ki ga opiše krivulja na intervalu  t∈[-1,1].
c) Izračunaj dolžino krivulje na intervalu t∈[-2,2].

2.a) Nariši krivuljo r=cos(3φ), ki je podana v polarnih koordinatah za ϕ∈[0,2π]. 
b) Izračunaj ploščino lika, ki ga krivulja omejuje.

3.a) Nariši graf funkcije f(x,y) = (x^2)+ 3x y2 + (y^2) + (y^3).
b) Poišči njene stacionarne točke.
c) Poišči globalni minimum in globalni maksimum funkcije f na pravokotniku omejenim s točkami A(-2,-2), B(3,-2), C(3,2) in D(-2,2).

4.a)  Integriraj funkcijo f(x,y)=1+sin(x) po pravokotniku -π≤x≤π, -1≤y≤1.
b) Integriraj funkcijo f(x,y)=xy po trikotniku omejenem s premico y =1+ x in pa x ter y osjo.