3. Optimal quadratic (G^0) approximant

In the quadratic  case control points determining the approximant  are given as

(Subscript[B, 0])[u_]=(((1-u))^2);(Subscript[B, 1])[u_]=2(1-u)u;(Subscript[B, 2])[u_]=(u^2);
(Subscript[b, 0])={c,-(Sqrt[1-(c^2)])};(Subscript[b, 1])={ξ,0};
(Subscript[b, 2])={c,(Sqrt[1-(c^2)])};
b20[t_,c_,ξ_]=Sum[(Subscript[b, j])(Subscript[B, j])[((t+1)/2)],{j,0,2}];
ψ20[t_,c_,ξ_]=((b20[t,c,ξ][[1]])^2)+((b20[t,c,ξ][[2]])^2)-1//FullSimplify;

where . The function $\psi$ is a quartic polynomial depending only on the parameter  and can be expressed as

ψ20[t,c,ξ]==(1/8) (1-(t^2)) (2 (1-(t^2))(ξ^2)+4 c (1+(t^2))ξ-8+2(c^2)(1-(t^2)))//Simplify

It increases on  for all  and . Thus, the optimal inner approximant is uniquely determined by the maximal  for which  and the optimal outer approximant is also uniquely given by the minimal  for which . Let us denote them as  and , respectively.
Since  is symmetric on , the parameter  is obtained as a solution of the equation , i.e.,  and  the parameter  is determined as a solution of the equation , i.e., . Note that in the latter case  we get the  approximant.

Optimal inner quadratic (G^0) approximant

Solve[ψ20[0,c,ξ]==0,ξ]

ξ20i[c_]=2-c;
Manipulate[Plot[ψ20[t,c,ξ20i[c]],{t,-1,1},GridLines->{{((Sqrt[2])/2)},{}}],{{c,(1/2)},0,1}]

The calculation of the optimal parameter and the error:

cc=((Sqrt[2])/2);
Print["The optimal parameter is (ξ^⋁)=", ξ20i[cc], " and the error is ",Simplify[ -ψ20[((Sqrt[2])/2),cc,ξ20i[cc]]],"=",N[ -ψ20[((Sqrt[2])/2),cc,ξ20i[cc]]],"."]

Optimal outer quadratic (G^0) approximant

Solve[D[ψ20[t,c,ξ],t]==0/.t->1,ξ]

ξ20o[c_]=(1/c);
Manipulate[Plot[ψ20[t,c,ξ20o[c]],{t,-1,1}],{{c,(1/2)},0,1}]

The calculation of the optimal parameter and the error:

cc=((Sqrt[2])/2);
Print["The optimal parameter is (ξ^⋀)=", ξ20o[cc], " and the error is ",Simplify[ψ20[0,cc,ξ20o[cc]]],"=",N[ψ20[0,cc,ξ20o[cc]]],"."]

4. Optimal cubic (G^1) approximant

In this case, the control points of an approximant  are given as

(Subscript[B, 0])[u_]=(((1-u))^3);(Subscript[B, 1])[u_]=3(((1-u))^2)u;(Subscript[B, 2])[u_]=3(1-u)(u^2);(Subscript[B, 3])[u_]=(u^3);
(Subscript[b, 0])={c,-(Sqrt[1-(c^2)])};(Subscript[b, 1])=(Subscript[b, 0])+ξ{(Sqrt[1-(c^2)]),c};
(Subscript[b, 3])={c,(Sqrt[1-(c^2)])};(Subscript[b, 2])=(Subscript[b, 3])+ξ{(Sqrt[1-(c^2)]),-c};
b31[t_,c_,ξ_]=Sum[(Subscript[b, j])(Subscript[B, j])[((t+1)/2)],{j,0,3}];
ψ31[t_,c_,ξ_]=((b31[t,c,ξ][[1]])^2)+((b31[t,c,ξ][[2]])^2)-1//FullSimplify;

where . Note that the  condition at the boundary points has already been incorporated. The error function  is a polynomial of degree 6, which can be written as

ψ31[t,c,ξ]==(1/16) (((1-(t^2)))^2) (9(ξ^2) ((t^2)(c^2)+1-(c^2))+12ξ(2-(t^2))(Sqrt[1-(c^2)])c-4(4-(t^2))(1-(c^2)))//Simplify

It is again clear that  is an increasing function for all  and . Since in addition  is  a polynomial of degree six with a positive leading coefficient, the parameter  of the optimal outer approximant must fulfil the condition , and consequently .
On the other hand, the condition for the approximant being an inner one is that  are triple zeros of , i.e.,   which implies the solution .

Optimal inner cubic (G^1) approximant

Solve[D[ψ31[t,c,ξ],{t,2}]==0/.t->1,ξ]//Simplify

Assuming[0<c<1,(2/3) (-c (Sqrt[1-(c^2)])+(Sqrt[3-2 (c^2)-(c^4)]))==(2/3) (Sqrt[1-(c^2)])((Sqrt[3+(c^2)])-c)//Simplify]

ξ31i[c_]=(2/3) (Sqrt[1-(c^2)])((Sqrt[3+(c^2)])-c);
Manipulate[Plot[ψ31[t,c,ξ31i[c]],{t,-1,1}],{{c,(1/2)},0,1}]

The calculation of the optimal parameter and the error:

cc=((Sqrt[2])/2);
Print["The optimal parameter is (ξ^⋁)=", Simplify[ξ31i[cc]], " and the error is ",Simplify[-ψ31[0,cc,ξ31i[cc]]],"=",N[-ψ31[0,cc,ξ31i[cc]]],"."]

Optimal outer cubic (G^1) approximant

Solve[ψ31[0,c,ξ]==0,ξ]//Simplify

ξ31o[c_]=((4 (Sqrt[1-(c^2)]))/(3(1+c)));
Manipulate[Plot[ψ31[t,c,ξ31o[c]],{t,-1,1},GridLines->{{((Sqrt[3])/3)},{}}],{{c,(1/2)},0,1}]

The calculation of the optimal parameter and the error:

cc=((Sqrt[2])/2);
Print["The optimal parameter is (ξ^⋀)=", Simplify[ξ31o[cc]], " and the error is ",Simplify[ψ31[((Sqrt[3])/3),cc,ξ31o[cc]]],"=",N[ψ31[((Sqrt[3])/3),cc,ξ31o[cc]]],"."]

5. Optimal quartic (G^2) approximant

As we will see in the following, the analysis gets much more complicated here as in the previous two cases. Considering  and  conditions, we can express control points of an approximant  as

(Subscript[B, 0])[u_]=(((1-u))^4);(Subscript[B, 1])[u_]=4(((1-u))^3)u;(Subscript[B, 2])[u_]=6(((1-u))^2)(u^2);(Subscript[B, 3])[u_]=4(1-u)(u^3);(Subscript[B, 4])[u_]=(u^4);
(Subscript[b, 0])={c,-(Sqrt[1-(c^2)])};(Subscript[b, 1])=(Subscript[b, 0])+ξ{(Sqrt[1-(c^2)]),c};(Subscript[b, 2])={((3-4(ξ^2))/(3c)),0};
(Subscript[b, 4])={c,(Sqrt[1-(c^2)])};(Subscript[b, 3])=(Subscript[b, 4])+ξ{(Sqrt[1-(c^2)]),-c};
b42[t_,c_,ξ_]=Sum[(Subscript[b, j])(Subscript[B, j])[((t+1)/2)],{j,0,4}];
ψ42[t_,c_,ξ_]=((b42[t,c,ξ][[1]])^2)+((b42[t,c,ξ][[2]])^2)-1//FullSimplify;

where again . The free parameter  was chosen similarly as in the previous section. The control point  is not defined for , but this case can be obtained as the limit . The function  is now a polynomial of degree 8, and with

α1=-(1/2) (Sqrt[1-(c^2)])((Sqrt[3+ (c^2)])+c);
α2=(1/2) (Sqrt[1-(c^2)])((Sqrt[3+ (c^2)])-c);
β1=(1/2) (c (Sqrt[1-(c^2)])-(Sqrt[3+8 c+6 (c^2)-(c^4)]));
β2=(1/2) (c (Sqrt[1-(c^2)])-(Sqrt[3-8 c+6 (c^2)-(c^4)]));
β3=(1/2) (c (Sqrt[1-(c^2)])+(Sqrt[3-8 c+6 (c^2)-(c^4)]));
β4=(1/2) (c (Sqrt[1-(c^2)])+(Sqrt[3+8 c+6 (c^2)-(c^4)]));

it can be written  as

ψ42[t,c,ξ]==(((((t^2)-1))^3)/(64(c^2)))(16(((ξ-α1))^2)(((ξ-α2))^2)(t^2)-16(ξ-β1)(ξ-β2)(ξ-β3)(ξ-β4))//Simplify

Unfortunately,  is no longer a monotone function, and a more involved analysis is needed. Observe first that

ψ42[0,c,ξ]==(1/(4(c^2)))(ξ-β1)(ξ-β2)(ξ-β3)(ξ-β4)//Simplify

and

γ1=(1/2) (c (Sqrt[1-(c^2)])-(Sqrt[3+6 (c^2)-(c^4)]));
γ2=(1/2) c (Sqrt[1-(c^2)]);
γ3=(1/2) (c (Sqrt[1-(c^2)])+(Sqrt[3+6 (c^2)-(c^4)]));D[ψ42[0,c,ξ],ξ]==(1/(c^2))(ξ-γ1)(ξ-γ2)(ξ-γ3)//Simplify

Let

td[c_,ξ_]=((48 (Sqrt[1-(c^2)]) (ξ^3))/c)+48 (ξ^2)-12(Sqrt[1-(c^2)]) (((3 )/c)+c ) ξ+12 (1-(c^2));
td[c,ξ]==(D[ψ42[t,c,ξ],{t,3}]/.t->1)//Simplify

Then

td[c,0]==12(1-(c^2))//Simplify
(D[td[c,ξ],ξ]/.ξ->0)==-(12/c)(Sqrt[1-(c^2)])(3+(c^2))//Simplify
Assuming[0<c<1,td[c,β3]==12(((1-c))^4)((((2+c)-(Sqrt[1+c])(Sqrt[3+c])))^2)//Simplify]

Furthermore,

δ1=((-2 c-(Sqrt[9-2 (c^2)-3 (c^4)]))/(6 (Sqrt[1-(c^2)])));
δ2=((-2 c+(Sqrt[9-2 (c^2)-3 (c^4)]))/(6 (Sqrt[1-(c^2)])));
D[td[c,ξ],ξ]==(144/c)(Sqrt[1-(c^2)])(ξ-δ1)(ξ-δ2)//Simplify
td[c,δ2]==-((48(((1-(c^2)))^3)(27-18(c^2)-(c^4)))/(c(8c(27(((1-(c^2)))^2)+22(c^2)-18(c^4))+4(9-2(c^2)-3(c^4))(Sqrt[9-2(c^2)-3(c^4)]))))//Simplify

It is easy to see

Plot[{α1,β1,γ1,δ1},{c,0,1},PlotLegends->"Expressions"]

Plot[{β2,γ2,δ2,β3,α2,γ3,β4},{c,0,1},PlotLegends->"Expressions"]

Optimal inner quartic (G^2) approximant

For

ξ42i[c_]=(1/2) (c (Sqrt[1-(c^2)])+(Sqrt[3-8 c+6 (c^2)-(c^4)]));
Manipulate[Plot[ψ42[t,c,ξ42i[c]],{t,-1,1}],{{c,(1/2)},0,1}]

we have

Assuming[0<c<1,ψ42[t,c,ξ42i[c]]==-(1/4)(((1-c))^4)(((2+c-(Sqrt[3+4c+(c^2)])))^2)(t^2)(((1-(t^2)))^3)//Simplify]

A parameter  does not induce an inner approximant since . Suppose . Since  is increasing on  there is , such that  for . If  induces a better approximant as , then the graphs of  and  have two intersection on , therefore ten intersections on , which is not possible. If , there are no  which induce an inner approximant.
Suppose  and . Since , the parameter  induces a better approximant then . Since  is decreasing on  a parameter  induces a worse approximant then . Therefore,  induces the optimal inner approximant. In the limit case, when , we get  and the abscissa of the control point  is .

The calculation of the optimal parameter and the error:

cc=((Sqrt[2])/2);
Print["The Optimal parameter is (ξ^⋁)=", Simplify[ξ42i[cc]], " and the error is ",Simplify[-ψ42[(1/2),cc,ξ42i[cc]]],"=",N[-ψ42[(1/2),cc,ξ42i[cc]]],"."]

The case c=0

ξξ=Limit[((3-4((ξ42i[c])^2))/(3c)),c->0]//Simplify
Print["The optimal parameter is (ξ^⋁)=", Simplify[ξξ], " and the error is ",Simplify[-Limit[ψ42[(1/2),c,ξ42i[c]],c->0]],"=",N[-Limit[ψ42[(1/2),c,ξ42i[c]],c->0]],"."]

Optimal outer quartic (G^2) approximant

Let  be the only zero of  on the interval . By the above calculations , so  induces an outer approximant. If , then , hence  does not induce an outer approximant. Suppose that . If , then  does not induce an outer approximant. Let . Since  the graphs of  and  intersect on . Hence, the graphs can not have an intersection on the interval , so  induces a worse approximant as .
In the limit case, when , we get  and the abscissa of the control point  is .

ξ42o[c_]=((Sqrt[9-2 (c^2)-3 (c^4)])/(3 (Sqrt[1-(c^2)])))Cos[(1/3)ArcCos[((2  c (27-32 (c^2)+9 (c^4)))/( (-9+2 (c^2)+3 (c^4))(Sqrt[9-2 (c^2)-3 (c^4)])))]]-(c/(3 (Sqrt[1-(c^2)])));
Manipulate[Plot[ψ42[t,c,ξ42o[c]],{t,-1,1}],{{c,(1/2)},0,1}]

The calculation of the optimal parameter and the error:

cc=((Sqrt[2])/2);
Print["The optimal parameter is (ξ^⋀)=", N[ξ42o[cc]], " and the error is ",N[ψ42[((Sqrt[3])/3),cc,ξ42o[cc]]],"."]

The case c=0

ξξ=Limit[((3-4((ξ42o[c])^2))/(3c)),c->0]//Simplify
Print["The optimal parameter is (ξ^⋁)=", Simplify[ξξ], " and the error is ",Simplify[Limit[ψ42[(1/2),c,ξ42o[c]],c->0]],"=",N[Limit[ψ42[(1/2),c,ξ42o[c]],c->0]],"."]

6. Optimal cubic (G^0) approximant

This section deals with cubic one-sided approximants of . The control points determining the approximant  are

(Subscript[B, 0])[u_]=(((1-u))^3);(Subscript[B, 1])[u_]=3(((1-u))^2)u;(Subscript[B, 2])[u_]=3(1-u)(u^2);(Subscript[B, 3])[u_]=(u^3);
(Subscript[b, 0])={c,-(Sqrt[1-(c^2)])};(Subscript[b, 1])={ξ,-η};
(Subscript[b, 2])={ξ,η};(Subscript[b, 3])={c,(Sqrt[1-(c^2)])};
b30[t_,c_,ξ_,η_]=Sum[(Subscript[b, j])(Subscript[B, j])[((t+1)/2)],{j,0,3}];
ψ30[t_,c_,ξ_,η_]=((b30[t,c,ξ,η][[1]])^2)+((b30[t,c,ξ,η][[2]])^2)-1//FullSimplify;

where . The function $\psi$ is of degree 6 and it is of the form

ψ30[t,c,ξ,η]==(1/16) ((t^2)-1) ((((3η-(Sqrt[1-(c^2)])))^2)(t^4)+(16(1-(c^2))-9 (((η+(Sqrt[1-(c^2)])))^2)+9 (((ξ-c))^2))(t^2)+(16-(((3ξ+c))^2)))//Simplify

hence

lc[c_,ξ_,η_]=(1/16)(((3η-(Sqrt[1-(c^2)])))^2);
lc[c,ξ,η]==Coefficient[ψ30[t,c,ξ,η],(t^6)]//Simplify
ψ30[0,c,ξ,η]==((1/16)(((3ξ+c))^2)-1)//Simplify
(D[ψ30[t,c,ξ,η],t]/.t->1)==3(1-ξ c-η(Sqrt[1-(c^2)]))//Simplify

We deal with the two-parametric optimization problem here, and the analysis is much more involved than in the previous cases. Let us consider the inner and the outer approximation separately again.

Optimal inner cubic (G^0) approximant

Following the idea of equioscillation of the best polynomial approximant in the functional case, we might expect equioscillation of . Since it is an inner approximant, it should touch the abscissa from below as many times as possible. Thus, the guess is that its graph looks like the one in Figure 1 (left). Since  is of degree 6 and it has two simple zeros at , the remaining two zeros on  should be double ones and related to the maxima of the Chebyshev polynomial of degree six.  Consequently, they equal to  and we must have
 .
It will be shown that the above system has a unique solution with , and that this solution implies the optimal approximant. Observe that (3) is an algebraic system of equations for  and . Two polynomials of a Gröbner basis for the ordering  are  and , where

g1[ξ_]=2187(ξ^3)+3807c (ξ^2)+(1953(c^2)−3840)ξ+245(c^3)−4352c;
g2[ξ_,η_]=−8 (1−(c^2)) η+(Sqrt[1−(c^2)]) (27(ξ^2)+10c ξ+3(c^2)−40);

GroebnerBasis[{ψ30[(1/2),c,ξ,η],(D[ψ30[t,c,ξ,η],t]/.t->(1/2))},{η,ξ}][[1;;2]]=={(ξ-c)g1[ξ],g2[ξ,η]}//Simplify

The zero  of  is not admissible, since the corresponding polynomial approximant reduces to the line segment, which definitely is not the optimal one. Thus, we are restricted to the positive zeros of . Let , where

(Subscript[ξ, min])=(1/27)(-5c+8(Sqrt[2])(Sqrt[9-(c^2)]));
(Subscript[ξ, max])=((4-c)/3);

Note that  for all .
Lemma 1. The only positive zero of  is in .
Proof. We have

g1[-(37/27)c]==(8192/9) c (1-(c^2))//Simplify
g1[0]==c(245 (c^2)-4352 )//Simplify
g1[(Subscript[ξ, min])]==-((2048(((1-(c^2)))^2))/((4c+(Sqrt[2])(Sqrt[9-(c^2)]))))//Simplify
g1[(Subscript[ξ, max])]==64(((1-c))^3)//Simplify

Since the leading coefficient of  is positive,  has two non-positive zeros and the unique positive one in . This completes the proof. 
Since  is a linear polynomial, the unique solution of the system (3) is , where  is the unique zero of  in , and
. 
Let , where

(Subscript[η, min])=((Sqrt[1-(c^2)])/3);
(Subscript[η, max])=((3-c)/(1+c))((Sqrt[1-(c^2)])/3);

Lemma 2. If  is the solution of the system (3),  then .
Proof. Let

f[ξ_]=((27(ξ^2)+10 c ξ+3(c^2)-40)/(8(Sqrt[1-(c^2)])));

Then

D[f[ξ],ξ]==((27ξ+5c)/(4(Sqrt[1-(c^2)])))//Simplify

and  is strictly increasing on . Thus

f[(Subscript[ξ, min])]==((Sqrt[1-(c^2)])/3)//Simplify
f[(Subscript[ξ, max])]==((3-c)/(1+c))((Sqrt[1-(c^2)])/3)//Simplify

Since  and  by (6), the proof is complete. 
We shall see in the following that  induces the polynomial approximant  with 
,
i.e., the optimal one.
Let us suppose that  induces a better approximant. If , then by (2) we have .
Thus , and  does not provide a smaller error than .
If  and , then by (2)
.
Consequently,  and  must intersect six times in  (see Figure 2 (left)) and at least twice out of , which contradicts the fact that  is of degree six. If  and , then , so  and  must intersect at least eight times in  (see Figure 2 (left) again), which can not be the case.
Thus, we are left with  and . The case where  is eliminated by using the same argument as in the previous case, and the following lemma eliminates the last case, i.e., .
Lemma 3. If ,  and , then  and  is not an inner approximant.
Proof. Since the pair of parameters  provides an inner approximant, we have . The assumptions of the lemma then imply
.
Thus , where  is the triangle given by (7) (see Figure 3 (left)). We need to show that  for , or, equivalently, that  lies outside of the ellipse  given by . The implicit equation of the ellipse reads

ψ30[(1/2),c,ξ,η]==(1/1024)(4(((9ξ+7c))^2)+(((9η+13(Sqrt[1-(c^2)])))^2)-1024)//Simplify

revealing that its centre is in the third quadrant. Thus, it is concave and decreasing in the first quadrant. The triangle  is above the line  given by the equation
.
Let $ be the tangent line of the ellipse  at . Note that the lines  and  intersect in  (see Figure 3 (left)). The result of the lemma will follow if we prove that the slope of  is greater than the slope of  since then the triangle  is out of the ellipse . Both slopes can be easily computed using (8) and (9) and we have to verify the inequality 
.
But it follows from the fact that  for  (we simply check the inequality at the corner points of ) and the fact that . 
Let us summarize the results in the following theorem.
Theorem 4. The optimal inner cubic  approximant of a circular arc is given by the pair of parameters , where  is a unique zero of  in  and  is a unique zero of  in .

The calculation of the optimal parameter and the error:

ξ30i[c_]=((32 (Sqrt[15+(c^2)]))/81)Cos[(1/3)ArcCos[((c(63+(c^2)))/(((15+(c^2)))^(3/2)))]]-((47 c)/81);
η30i[c_]=((27((ξ30i[c])^2)+10c ξ30i[c]+3(c^2)-40)/(8(Sqrt[1-(c^2)])));
Manipulate[Plot[ψ30[t,c,ξ30i[c],η30i[c]],{t,-1,1},GridLines->{{((Sqrt[3])/2)},{}}],{{c,(1/2)},0,1}]

cc=((Sqrt[2])/2);
Print["The pair of optimal parameters is {(ξ^⋁),(η^⋁)}=", {N[ξ30i[cc]],N[η30i[cc]]}, " and the error is ",N[-ψ30[((Sqrt[3])/2),cc,ξ30i[cc],η30i[cc]]],"."]

Optimal outer cubic (G^0) approximant

We will show that the optimal outer approximant is  approximant. From the equations  and  we get

ξ30o[c_]=((4-c)/3);
η30o[c_]=((3-4c+(c^2))/(3(Sqrt[1-(c^2)])));

Suppose that a pair  induces a better outer approximant. From  we get . From 

we get . From

ψ30[((Sqrt[3])/3),c,ξ,η]==(1/108)((((3η+5(Sqrt[1-(c^2)])))^2)+27(((ξ+c))^2)-108)//Simplify

we get . From the last two inequalities we get
 

.
The last inequality follows since . Hence all inequalites are equalities, so .

The calculation of the optimal parameter and the error:

cc=((Sqrt[2])/2);
Print["The pair of optimal parameter is {(ξ^⋀),(η^⋀)}=", {N[ξ30o[cc]],N[η30o[cc]]}, " and the error is ",N[ψ30[((Sqrt[3])/3),cc,ξ30o[cc],η30o[cc]]],"."]

7. Optimal quartic (G^1) approximant

In the  quartic case the control points of an approximant  are given as

(Subscript[B, 0])[u_]=(((1-u))^4);(Subscript[B, 1])[u_]=4(((1-u))^3)u;(Subscript[B, 2])[u_]=6(((1-u))^2)(u^2);(Subscript[B, 3])[u_]=4(1-u)(u^3);(Subscript[B, 4])[u_]=(u^4);
(Subscript[b, 0])={c,-(Sqrt[1-(c^2)])};(Subscript[b, 1])={c,-(Sqrt[1-(c^2)])}+ξ{(Sqrt[1-(c^2)]),c};(Subscript[b, 2])={η,0};
(Subscript[b, 3])={c,(Sqrt[1-(c^2)])}+ξ{(Sqrt[1-(c^2)]),-c};(Subscript[b, 4])={c,(Sqrt[1-(c^2)])};
b41[t_,c_,ξ_,η_]=Sum[(Subscript[b, j])(Subscript[B, j])[((t+1)/2)],{j,0,4}];
ψ41[t_,c_,ξ_,η_]=((b41[t,c,ξ,η][[1]])^2)+((b41[t,c,ξ,η][[2]])^2)-1//FullSimplify;

where  due to the  continuity. The function  is again a polynomial of degree 8 and can be written as

lc[c_,ξ_,η_]=(1/64) (((3η-4(Sqrt[1-(c^2)])ξ-3c))^2);
a1[c_,ξ_,η_]=(1/64)(32(c^2)(ξ^2)+32(ξ^2)−64c(Sqrt[1−(c^2)])ξ−18(η^2)+36c η−34(c^2)+16);
a0[c_,ξ_,η_]=(1/64)((((3η+4(Sqrt[1−(c^2)])ξ+5c))^2)−64);
ψ41[t,c,ξ,η]==((((t^2)-1))^2)(lc[c,ξ,η](t^4)+a1[c,ξ,η](t^2)+a0[c,ξ,η])//Simplify
(D[ψ41[t,c,ξ,η],{t,2}]/.t->1)==8(ξ^2)+6c η−6//Simplify

Optimal inner quartic (G^1) approximant

It will turn out that the optimal inner quartic  approximant is actually the optimal  approximant from Section 5.1. Recall that, in this case, we have  and , and the appropriate solution which induces the best approximant is given by

ξ41i[c_]=((c(1-(c^2))+(((1-c))^2) (Sqrt[3+4 c+(c^2)]))/(2 (Sqrt[1-(c^2)])));
η41i[c_]=(1/3) (8-7 c+2 (c^3)-2 (((1-c))^2)(Sqrt[3+4 c+(c^2)]));

Manipulate[Plot[ψ41[t,c,ξ41i[c],η41i[c]],{t,-1,1},GridLines->{{(1/2)},{}}],{{c,(1/2)},0,1}]

with the error

-ψ41[(1/2),c,ξ41i[c],η41i[c]]==(1/1024)(27(((1-c))^4)((((2+c)-(Sqrt[3+4c+(c^2)])))^2))//Simplify

Plot[(1/1024)(27(((1-c))^4)((((2+c)-(Sqrt[3+4c+(c^2)])))^2)),{c,0,1},GridLines->{{},{((27(((2-(Sqrt[3])))^2))/1024)}}]

Suppose that a pair  induces the optimal inner  approximant. By Section 5.1, we know that the induced approximant is not a  approximant. First, we show that .
Suppose that . Since , we have . Then

.
Together with the inequality  we get that  for all  close but not equal to 1. Hence the graphs of  and  have one intersection on  and one on . Since they have at least double zeros at , they have at most two intersections on , so there are no intersections on . Hence  induces a worse  inner approximant then , hence .
Since  and , where

(Subscript[b, 2])=(9/64) (((1−(t^2)))^4);
(Subscript[b, 1])=(3/32)(((1−(t^2)))^2) (c (5+6(t^2)−3(t^4))+4(Sqrt[1−(c^2)]) (1−(t^4)) ξ);
ψ41[t,c,ξ,η]==(Subscript[b, 2]) (η^2)+(Subscript[b, 1]) η+ψ41[t,c,ξ,0]//Simplify

for all , the function  is increasing. If  we can enlarge  and get better inner  approximant. Hence  and therefore . If $ then , so  does not induce an inner approximant. If , then , hence  induces worse approximant then .

Optimal outer quartic (G^1) approximant

In order to simplify the coefficients of the polynomial , we introduce two new variables 

which implies  and . Now  can be written as  and we get

ψuv[t_,c_,u_,v_]=ψ41[t,c,((v-u)/(8(Sqrt[1-(c^2)]))),(1/6)(u+v)];
Coefficient[ψuv[t,c,u,v],(t^8)]==(1/64)(((u-3c))^2)//Simplify
ψuv[0,c,u,v]==(1/64)((((v+5c))^2)-64)//Simplify
(D[ψuv[t,c,u,v],{t,2}]/.t->1)==((((v-u))^2)/(8(1-(c^2))))+c(v+u)-6//Simplify

Observe that  due to the  interpolation condition and  since the approximant is the outer one. This implies
.
Let us first assume that .
It is clear that  is symmetric and has two double zeros at . Following the idea of equioscillation of the best polynomial approximant in the functional case, we might expect that  equioscillates. Since it is an outer approximant, it may touch the abscissa several times. Thus, the guess is that its graph looks like on Figure 1 (right). But then its four double zeros on  must be related to the minima of the Chebyshev polynomial of degree eight. Consequently, the two double zeros on  are equal to  and . Since these points are also minima of , we must have
.
This leads to the system of two algebraic equations for  and . Its Gröbner basis according to the ordering  are polynomials  and , given as
,
where

(Subscript[α, 4])=(c^2)((c^2)+1);(Subscript[α, 3])=−8(3+(Sqrt[2]))(c^5)+4(4+5(Sqrt[2]))(c^3)+4(4+3(Sqrt[2]))c;(Subscript[α, 2])=2(125+68(Sqrt[2]))(c^6)−2(229+182(Sqrt[2]))(c^4)+4(140+97(Sqrt[2]))(c^2)−4(65+46(Sqrt[2]));
(Subscript[α, 1])=−88(14+9(Sqrt[2]))(c^7)+12(116+89(Sqrt[2]))(c^5)−84(16+11(Sqrt[2]))(c^3)+4(50+36(Sqrt[2]))c;(Subscript[α, 0])=5(457+312(Sqrt[2]))(c^8)−(1655+1236(Sqrt[2]))(c^6)+12(16+9(Sqrt[2]))(c^4)+4(163+114(Sqrt[2]))(c^2)+272+192(Sqrt[2]);
p1[u_]=(1/(1-(c^2)))((Subscript[α, 4]) (u^4)+(Subscript[α, 3]) (u^3)+(Subscript[α, 2]) (u^2)+(Subscript[α, 1]) (u^1)+(Subscript[α, 0]));

and
,
where

(Subscript[β, 1])=-2 (3+2 (Sqrt[2])+2 (c^2)-(1+6 (Sqrt[2])) (c^4)+4 (4+(Sqrt[2])) (c^6)+4 (c^8));
(Subscript[β, 0])[u_]=36 (3-2 (Sqrt[2])) (c^9)+16 (3 (Sqrt[2])-5) (c^8) u+ (329-198 (Sqrt[2])+(12-8 (Sqrt[2])) (u^2))(c^7)+(142 (Sqrt[2])-253) (c^6) u+ (169-198 (Sqrt[2])+(55-34 (Sqrt[2])) (u^2))(c^5)+(174 (Sqrt[2])-51+(2 (Sqrt[2])-3) (u^2))(c^4) u + (4 (43+9 (Sqrt[2]))-5 (6 (Sqrt[2])-7) (u^2))(c^3)-(16 (7+3 (Sqrt[2])) u+(3-2 (Sqrt[2])) (u^3))(c^2) +2 (23+16 (Sqrt[2])) u-4 c (10+9 (Sqrt[2])+(Sqrt[2]) (u^2));
p2[u_,v_]=(1/((c^2)-1))((Subscript[β, 1]) v +(Subscript[β, 0])[u]);
GroebnerBasis[{Simplify[ψuv[(Sqrt[2])-1,c,u,v]],Simplify[(D[ψuv[t,c,u,v],t]/.t->(Sqrt[2])-1)]},{v,u}]=={p1[u],p2[u,v]}//Simplify

Let us define the domain of interest for  as
,
where

(OverTilde[u])=k (c^2)-(2k-3)c+k/.k->2(Sqrt[((2(Sqrt[2])-1)/7)]);

Note that  is a subset of (11). We shall prove in the following that there exists a unique  solution  of (12) with  the unique zero of  on  and . Moreover, this solution is optimal, i.e., it induces the polynomial approximant  with  for which 
.
Let us first confirm the following lemma.
Lemma 5. The polynomial  has precisely one zero  on , and the system (12) has precisely one solution  in .
Proof. By (13) and (14) the leading coefficient of  is

Coefficient[p1[u],(u^4)]==(((c^2) +(c^4))/(1-(c^2)))//Simplify

thus . A computer algebra system reveals that

a={-4 (11757+8314 (Sqrt[2])),-20 (20970+14827 (Sqrt[2])),-5 (300175+212256 (Sqrt[2])),-2868170-2028204 (Sqrt[2]),-10 (328607+232384 (Sqrt[2])),-8 (301424+213155 (Sqrt[2])),-16 (71127+50296 (Sqrt[2])),-1152 (239+169 (Sqrt[2]))};
(1+c)p1[-6(Sqrt[2])-5]==Total[Table[a[[i+1]](c^i)(((1-c))^(7-i)),{i,0,7}]]//Simplify
b={272+192 (Sqrt[2]),1740+1224 (Sqrt[2]),36 (105+73 (Sqrt[2])),9 (197+124 (Sqrt[2])),18 (97+60 (Sqrt[2]))};
(1-(c^2))p1[0]==Total[Table[b[[i+1]](c^(2i))(((1-(c^2)))^(4-i)),{i,0,4}]]//Simplify
p1[3c]==16 (17+12 (Sqrt[2])) (((1-(c^2)))^3)//Simplify
d={-((28 (468177+331052 (Sqrt[2])))/(196 (17+12 (Sqrt[2]))+1174 (Sqrt[-7+14 (Sqrt[2])])+830 (Sqrt[-14+28 (Sqrt[2])]))),-((1023648947+723832272 (Sqrt[2]))/(30571+21584 (Sqrt[2])+10630 (Sqrt[-7+14 (Sqrt[2])])+7510 (Sqrt[-14+28 (Sqrt[2])]))),-((44 (334596323+236596644 (Sqrt[2])))/(116750+82480 (Sqrt[2])+40512 (Sqrt[-7+14 (Sqrt[2])])+28610 (Sqrt[-14+28 (Sqrt[2])]))) ,-((8 (8319080395+5882517894 (Sqrt[2])))/(84728 (Sqrt[-7+14 (Sqrt[2])])+59822 (Sqrt[-14+28 (Sqrt[2])])+4 (60467+42733 (Sqrt[2])))),-((4(6933599848+4902830366 (Sqrt[2])))/(73675+52080 (Sqrt[2])+26381 (Sqrt[-7+14 (Sqrt[2])])+18624 (Sqrt[-14+28 (Sqrt[2])]))),-((224 (301412347+213132210 (Sqrt[2])))/(78508 (Sqrt[-7+14 (Sqrt[2])])+55420 (Sqrt[-14+28 (Sqrt[2])])+28 (7577+5356 (Sqrt[2])))),-((112(1009965+714158 (Sqrt[2])))/( 750+530 (Sqrt[2])+289 (Sqrt[-7+14 (Sqrt[2])])+204 (Sqrt[-14+28 (Sqrt[2])]))),-((28(550063+388956 (Sqrt[2])))/(507+358 (Sqrt[2])+204 (Sqrt[-7+14 (Sqrt[2])])+144 (Sqrt[-14+28 (Sqrt[2])])))};
49 (1+c) p1[(OverTilde[u])]==16 c(((1-c))^3)Total[Table[d[[i+1]](c^i)(((1-c))^(7-i)),{i,0,7}]]//Simplify

Thus , , , and  and the result of the lemma follows since  is quartic. 
Let us confirm that the solution  induces the optimal approximant. If not, then there exists a pair  , , for which
.
If , then  since  by (11), and  can not induce better approximant than . Thus . Consider first the case . By Lemma 5  and (10) implies . If , then the graphs of  and  intersect on . Moreover, if  induces a better approximant as , then the graphs of  and  would have to intersect at least eight times on , which is not possible since  is a polynomial of degree at most 8 (see Figure 2 (right)). Similarly, if , the above-mentioned graphs would have to intersect at least ten times on  which is again a contradiction. Finally, let us consider the case  and . If , then the graphs of  and  would have to intersect at least ten times on  which is again an obvious contradiction. So, we are left with the case . The following lemma reveals that, in this case, the approximant is not an outer one.

u41o[c_]=-((4 (Sqrt[249+176 (Sqrt[2])-(217+152 (Sqrt[2])) (c^2)+2 (c^4)]))/(3 c))Cos[(1/3)ArcCos[(((5555+3928 (Sqrt[2])-3 (2423+1713 (Sqrt[2])) (c^2)+3 (478+337 (Sqrt[2])) (c^4)+2 (Sqrt[2]) (c^6)))/(((249+176 (Sqrt[2])-(217+152 (Sqrt[2])) (c^2)+2 (c^4)))^(3/2)))]-((4π)/3)]+((-22-16 (Sqrt[2])+15 (c^2)+4 (Sqrt[2]) (c^2))/(3 c));
v41o[c_]=-(((Subscript[β, 0])[u41o[c]])/(Subscript[β, 1]));
Manipulate[Plot[ψuv[t,c,u41o[c],v41o[c]],{t,-1,1}],{{c,(1/2)},0,1}]

Lemma 6. Let  and . If , then .
Proof. Let us define

f[u_,v_]=(D[ψuv[t,c,u,v],{t,2}]-D[ψuv[t,c,u41o[c],v41o[c]],{t,2}]/.t->1);
g[u_,v_]=ψuv[(Sqrt[2])-1,c,u,v];

Observe that  is a parabola

Det[{{Coefficient[f[u,v],(u^2)],(1/2)Coefficient[f[u,v],u v]},
{(1/2)Coefficient[f[u,v],u v],Coefficient[f[u,v],(v^2)]}}]==0//Simplify

and  is an ellipse (see Figure 3, right)

Det[{{Coefficient[g[u,v],(u^2)],(1/2)Coefficient[g[u,v],u v]},
{(1/2)Coefficient[g[u,v],u v],Coefficient[g[u,v],(v^2)]}}]==(((577-408 (Sqrt[2])) (c^2))/(64 (1-(c^2))))//Simplify

with leading coefficients of their tangent lines at  equal to

cp[u_,v_]=((4 (c^3)-4 c-u+v)/(-4 (c^3)+4 c-u+v));
ce[u_,v_]=(((12 (Sqrt[2])-17) u+2c(15-11 (Sqrt[2])+(11 (Sqrt[2])-15) (c^2)+(7-5 (Sqrt[2])) c u)+(3-2 (Sqrt[2])) v)/((2 (Sqrt[2])-3) u+v+2c(1+(Sqrt[2])-c((1+(Sqrt[2])) c+((Sqrt[2])-1) v))));
-((D[f[u,v],u])/(D[f[u,v],v]))==cp[u,v]//Simplify
-((D[g[u,v],u])/(D[g[u,v],v]))==ce[u,v]//Simplify

respectively. With the help of a computer algebra system, it can be again shown that

cp1={{{8,9},{8-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))]),9-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])}},{{12,15},{12-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))]),15-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])}},{{0,3},{0,3}},{{0,1},{0,1}}};cp2={{{8,9},{8-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))]),9-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])}},{{20,23},{20-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))]),23-2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])}},{{16,19},{16,19}},{{0,1},{0,1}}};
And@@Map[#>=0&,Flatten[Join[cp1,cp2]]]
cp[(1-u)3c+u  (OverTilde[u]),v+8-5c]==Total[Flatten[Table[cp1[[i+1,j+1,k+1]](((1-c))^(3-i))(c^i)(((1-u))^(1-j))(u^j)(((1-v))^(1-k))(v^k),{i,0,3},{j,0,1},{k,0,1}]]]/Total[Flatten[Table[cp2[[i+1,j+1,k+1]](((1-c))^(3-i))(c^i)(((1-u))^(1-j))(u^j)(((1-v))^(1-k))(v^k),{i,0,3},{j,0,1},{k,0,1}]]]//Simplify

ce1={{{24-16 (Sqrt[2]),27-18 (Sqrt[2])},{24-16 (Sqrt[2])+(2/7) (-17+12 (Sqrt[2])) (Sqrt[-7+14 (Sqrt[2])]),27-18 (Sqrt[2])+(2/7) (-17+12 (Sqrt[2])) (Sqrt[-7+14 (Sqrt[2])])}},{{60-40 (Sqrt[2]),72-48 (Sqrt[2])},{60-40 (Sqrt[2])-68 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])+48 (Sqrt[(2/7) (-1+2 (Sqrt[2]))]),72-48 (Sqrt[2])-68 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])+48 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])}},{{36-24 (Sqrt[2]),54-36 (Sqrt[2])},{(2/7) (-3+2 (Sqrt[2])) (-42+(Sqrt[-7+14 (Sqrt[2])])),(2/7) (-3+2 (Sqrt[2])) (-63+(Sqrt[-7+14 (Sqrt[2])]))}},{{0,12-8 (Sqrt[2])},{0,12-8 (Sqrt[2])}},{{0,3-2 (Sqrt[2])},{0,3-2 (Sqrt[2])}}};
ce2={{{8,9},{8+(2/7) (-3+2 (Sqrt[2])) (Sqrt[-7+14 (Sqrt[2])]),9+(2/7) (-3+2 (Sqrt[2])) (Sqrt[-7+14 (Sqrt[2])])}},{{20+8 (Sqrt[2]),8 (3+(Sqrt[2]))},{20+8 (Sqrt[2])-12 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])+8 (Sqrt[(2/7) (-1+2 (Sqrt[2]))]),8 (3+(Sqrt[2]))-12 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])+8 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])}},{{28+8 (Sqrt[2]),6 (6+(Sqrt[2]))},{28+8 (Sqrt[2])-6 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])+4 (Sqrt[(2/7) (-1+2 (Sqrt[2]))]),6 (6+(Sqrt[2]))-6 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])+4 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])}},{{16,-4 (-6+(Sqrt[2]))},{16,-4 (-6+(Sqrt[2]))}},{{0,3-2 (Sqrt[2])},{0,3-2 (Sqrt[2])}}};
And@@Map[#>=0&,Flatten[Join[ce1,ce2]]]
ce[(1-u)3c+u  (OverTilde[u]),v+8-5c]==Total[Flatten[Table[ce1[[i+1,j+1,k+1]](((1-c))^(4-i))(c^i)(((1-u))^(1-j))(u^j)(((1-v))^(1-k))(v^k),{i,0,4},{j,0,1},{k,0,1}]]]/Total[Flatten[Table[ce2[[i+1,j+1,k+1]](((1-c))^(4-i))(c^i)(((1-u))^(1-j))(u^j)(((1-v))^(1-k))(v^k),{i,0,4},{j,0,1},{k,0,1}]]]//Simplify

and  for .

cc={{{128 (-1+(Sqrt[2])),288 (-1+(Sqrt[2])),162 (-1+(Sqrt[2]))},{-(64/7) (28-28 (Sqrt[2])-4 (Sqrt[-7+14 (Sqrt[2])])+3 (Sqrt[-14+28 (Sqrt[2])])),-(8/7) (-504 (-1+(Sqrt[2]))-68 (Sqrt[-7+14 (Sqrt[2])])+51 (Sqrt[-14+28 (Sqrt[2])])),-(36/7) (63-63 (Sqrt[2])-8 (Sqrt[-7+14 (Sqrt[2])])+6 (Sqrt[-14+28 (Sqrt[2])]))},{-(8/7) (85-93 (Sqrt[2])-32 (Sqrt[-7+14 (Sqrt[2])])+24 (Sqrt[-14+28 (Sqrt[2])])),-(8/7) (198-214 (Sqrt[2])-68 (Sqrt[-7+14 (Sqrt[2])])+51 (Sqrt[-14+28 (Sqrt[2])])),(1/7) (-918+982 (Sqrt[2])+288 (Sqrt[-7+14 (Sqrt[2])])-216 (Sqrt[-14+28 (Sqrt[2])]))}},{{704 (-1+(Sqrt[2])),1608 (-1+(Sqrt[2])),918 (-1+(Sqrt[2]))},{-(16/7) (616-616 (Sqrt[2])-73 (Sqrt[-7+14 (Sqrt[2])])+55 (Sqrt[-14+28 (Sqrt[2])])),-(8/7) (-2814 (-1+(Sqrt[2]))-312 (Sqrt[-7+14 (Sqrt[2])])+235 (Sqrt[-14+28 (Sqrt[2])])),-(4/7) (-3213 (-1+(Sqrt[2]))-332 (Sqrt[-7+14 (Sqrt[2])])+250 (Sqrt[-14+28 (Sqrt[2])]))},{-(8/7) (535-559 (Sqrt[2])-146 (Sqrt[-7+14 (Sqrt[2])])+110 (Sqrt[-14+28 (Sqrt[2])])),-(8/7) (1245-1293 (Sqrt[2])-312 (Sqrt[-7+14 (Sqrt[2])])+235 (Sqrt[-14+28 (Sqrt[2])])),-(2/7) (2889-2985 (Sqrt[2])-664 (Sqrt[-7+14 (Sqrt[2])])+500 (Sqrt[-14+28 (Sqrt[2])]))}},{{1408 (-1+(Sqrt[2])),3312 (-1+(Sqrt[2])),1944 (-1+(Sqrt[2]))},{-(64/7) (-29 (Sqrt[-7+14 (Sqrt[2])])+22 (14-14 (Sqrt[2])+(Sqrt[-14+28 (Sqrt[2])]))),-(8/7) (-5796 (-1+(Sqrt[2]))-500 (Sqrt[-7+14 (Sqrt[2])])+379 (Sqrt[-14+28 (Sqrt[2])])),3888 (-1+(Sqrt[2]))+2144 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])-232 (Sqrt[-14+28 (Sqrt[2])])},{-(16/7) (589-597 (Sqrt[2])-116 (Sqrt[-7+14 (Sqrt[2])])+88 (Sqrt[-14+28 (Sqrt[2])])),-(8/7) (2790-2822 (Sqrt[2])-500 (Sqrt[-7+14 (Sqrt[2])])+379 (Sqrt[-14+28 (Sqrt[2])])),-(8/7) (1647-1663 (Sqrt[2])-268 (Sqrt[-7+14 (Sqrt[2])])+203 (Sqrt[-14+28 (Sqrt[2])]))}},{{1216 (-1+(Sqrt[2])),3064 (-1+(Sqrt[2])),1908 (-1+(Sqrt[2]))},{-864 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])+32 (76 (-1+(Sqrt[2]))+5 (Sqrt[-7+14 (Sqrt[2])])),6128 (-1+(Sqrt[2]))-1896 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])+352 (Sqrt[-7+14 (Sqrt[2])]),3816 (-1+(Sqrt[2]))-1032 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])+192 (Sqrt[-7+14 (Sqrt[2])])},{-864 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])+32 (38 (-1+(Sqrt[2]))+5 (Sqrt[-7+14 (Sqrt[2])])),3064 (-1+(Sqrt[2]))-1896 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])+352 (Sqrt[-7+14 (Sqrt[2])]),1908 (-1+(Sqrt[2]))-1032 (Sqrt[(2/7) (-1+2 (Sqrt[2]))])+192 (Sqrt[-7+14 (Sqrt[2])])}},{{384 (-1+(Sqrt[2])),1216 (-1+(Sqrt[2])),882 (-1+(Sqrt[2]))},{-(64/7) (-1+(Sqrt[2])) (-84+(Sqrt[-7+14 (Sqrt[2])])),2432 (-1+(Sqrt[2]))+192 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])-176 (Sqrt[(2/7) (-1+2 (Sqrt[2]))]),1764 (-1+(Sqrt[2]))+128 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])-16 (Sqrt[-14+28 (Sqrt[2])])},{-(64/7) (-1+(Sqrt[2])) (-42+(Sqrt[-7+14 (Sqrt[2])])),-(16/7) (-532 (-1+(Sqrt[2]))-12 (Sqrt[-7+14 (Sqrt[2])])+11 (Sqrt[-14+28 (Sqrt[2])])),882 (-1+(Sqrt[2]))+128 (Sqrt[(1/7) (-1+2 (Sqrt[2]))])-16 (Sqrt[-14+28 (Sqrt[2])])}},{{0,176 (-1+(Sqrt[2])),198 (-1+(Sqrt[2]))},{0,352 (-1+(Sqrt[2])),396 (-1+(Sqrt[2]))},{0,176 (-1+(Sqrt[2])),198 (-1+(Sqrt[2]))}},{{0,32 (-1+(Sqrt[2])),36 (-1+(Sqrt[2]))},{0,64 (-1+(Sqrt[2])),72 (-1+(Sqrt[2]))},{0,32 (-1+(Sqrt[2])),36 (-1+(Sqrt[2]))}},{{0,0,0},{0,0,0},{0,0,0}}};
And@@Map[#>=0&,Flatten[cc]]
Simplify[((4 (c^3)-4 c-u+v)((2 (Sqrt[2])-3) u+v+2c(1+(Sqrt[2])-c((1+(Sqrt[2])) c+((Sqrt[2])-1) v)))-((12 (Sqrt[2])-17) u+2c(15-11 (Sqrt[2])+(11 (Sqrt[2])-15) (c^2)+(7-5 (Sqrt[2])) c u)+(3-2 (Sqrt[2])) v)(-4 (c^3)+4 c-u+v))/.{u->(1-u)3c+u  (OverTilde[u]),v->v+8-5c}]==Total[Flatten[Table[cc[[i+1,j+1,k+1]](((1-c))^(7-i))(c^i)(((1-u))^(2-j))(u^j)(((1-v))^(2-k))(v^k),{i,0,7},{j,0,2},{k,0,2}]]]//Simplify

Thus, by (11) and Lemma 5, all these inequalities hold for  and . The parabola and the ellipse intersect at , and , . Since in addition the ordinate of the intersection of tangent lines with -axis is positive, the parabola and the ellipse are concave at . This implies
 and the result of the lemma is confirmed. Since, in addition, the ordinate of the intersection of the tangent line to ellipse with -axis is positive, and the parabola is symmetric about the line , the parabola and ellipse are concave at . 
Finally, consider . By (11) we have , therefore , and . From the above calculation we have . Hence, if the pair  induces a better outer approximant than the pair , then the error graphs of induced approximants have at least ten intersections, which is impossible. We can now finally formulate the main result of this subsection.
Theorem 7. The optimal quartic  outer approximant is given by the unique solution of the nonlinear algebraic system (12) on the domain .
Remark 8. Note that although the zeros of  given by (13) can be found analytically (since  is a quartic polynomial),  it is much more efficient to compute the appropriate zero on  by some numerical method since the interval of interest provides a good starting point.

The calculation of the optimal parameter and the error:

ξ41o[c_]=((v41o[c]-u41o[c])/(8(Sqrt[1-(c^2)])));
η41o[c_]=((v41o[c]+u41o[c])/6);

cc=((Sqrt[2])/2);
Print["The pair of optimal parameters is {(ξ^⋀),(η^⋀)}=", {N[ξ41o[cc]],N[η41o[cc]]}, " and the error is ",N[ψ41[0,cc,ξ41o[cc],η41o[cc]]],"."]

8. Numerical examples

In this section, several numerical examples will be presented in order to confirm the theoretical results derived in the previous 
sections. The quality of optimal inner and outer approximants will be compared to the general optimal approximants obtained in [5] where the Hausdorff distance has been considered as a measure of quality. Note that in the case of inner and outer approximants, the radial distance coincides with the Hausdorff one, too.
For the parabolic  case, the optimal parameters and radial distances for several inner angles of a circular arc are collected in Table 1. The optimal parameters and corresponding radial distances for the cubic  and the cubic  case are in Table 2 and Table 3, respectively.
As we have seen in Section 7, the quartic  case is probably the most interesting. Optimal parameters with the corresponding radial distances are in Table 4. There always exist four outer admissible solutions arising from the zeros of  given by (13) but they provide quite different approximants. The best two are on Figure 5. They look quite similar, but the radial errors differ significantly. The other two approximants correspond to two additional sets of parameters. Their graphs are presented on Figure 6. It is seen that they represent the approximation of the complementary circular arc. This is because the radial error 
at a particular point on the curve is measured in the radial direction from this point to the circle (which is not necessarily a part of the considered circular arc). We guess that these solutions imply the optimal approximants of the complementary arc (see [3]).
Finally, the optimal parameters with the corresponding radial distances for the quartic  case are collected in Table 5.

Error functions and optimal parameters

ψ20[t_,c_,ξ_]=(1/8) (1-(t^2)) (2 (1-(t^2))(ξ^2)+4 c (1+(t^2))ξ-8+2(c^2)(1-(t^2)));
ϕ20[t_,c_,ξ_]=(Sqrt[ψ20[t,c,ξ]+1])-1;
ξ20i[c_]=2-c;
ξ20o[c_]=(1/c);
ψ31[t_,c_,ξ_]=(1/16) (((1-(t^2)))^2) (9(ξ^2) ((t^2)(c^2)+1-(c^2))+12ξ(2-(t^2))(Sqrt[1-(c^2)])c-4(4-(t^2))(1-(c^2)));
ϕ31[t_,c_,ξ_]=(Sqrt[ψ31[t,c,ξ]+1])-1;
ξ31i[c_]=(2/3) (Sqrt[1-(c^2)])((Sqrt[3+(c^2)])-c);
ξ31o[c_]=((4 (Sqrt[1-(c^2)]))/(3(1+c)));
ψ42[t_,c_,ξ_]=(((((t^2)-1))^3)/(64(c^2)))(16(((ξ+(1/2) (Sqrt[1-(c^2)])((Sqrt[3+ (c^2)])+c)))^2)(((ξ-(1/2) (Sqrt[1-(c^2)])((Sqrt[3+ (c^2)])-c)))^2)(t^2)-16(ξ-(1/2) (c (Sqrt[1-(c^2)])-(Sqrt[3+8 c+6 (c^2)-(c^4)])))(ξ-(1/2) (c (Sqrt[1-(c^2)])-(Sqrt[3-8 c+6 (c^2)-(c^4)])))(ξ-(1/2) (c (Sqrt[1-(c^2)])+(Sqrt[3-8 c+6 (c^2)-(c^4)])))(ξ-(1/2) (c (Sqrt[1-(c^2)])+(Sqrt[3+8 c+6 (c^2)-(c^4)]))));
ϕ42[t_,c_,ξ_]=(Sqrt[ψ42[t,c,ξ]+1])-1;
ξ42i[c_]=(1/2) (c (Sqrt[1-(c^2)])+(Sqrt[3-8 c+6 (c^2)-(c^4)]));
ξ42o[c_]=((Sqrt[9-2 (c^2)-3 (c^4)])/(3 (Sqrt[1-(c^2)])))Cos[(1/3)ArcCos[((2  c (27-32 (c^2)+9 (c^4)))/( (-9+2 (c^2)+3 (c^4))(Sqrt[9-2 (c^2)-3 (c^4)])))]]-(c/(3 (Sqrt[1-(c^2)])));
ψ30[t_,c_,ξ_,η_]=(1/16) ((t^2)-1) ((((3η-(Sqrt[1-(c^2)])))^2)(t^4)+(16(1-(c^2))-9 (((η+(Sqrt[1-(c^2)])))^2)+9 (((ξ-c))^2))(t^2)+(16-(((3ξ+c))^2)));
ϕ30[t_,c_,ξ_,η_]=(Sqrt[ψ30[t,c,ξ,η]+1])-1;
ξ30i[c_]=((32 (Sqrt[15+(c^2)]))/81)Cos[(1/3)ArcCos[((c(63+(c^2)))/(((15+(c^2)))^(3/2)))]]-((47 c)/81);
η30i[c_]=((27((ξ30i[c])^2)+10c ξ30i[c]+3(c^2)-40)/(8(Sqrt[1-(c^2)])));
ξ30o[c_]=((4-c)/3);
η30o[c_]=((3-4c+(c^2))/(3(Sqrt[1-(c^2)])));
ψ41[t_,c_,ξ_,η_]=((((t^2)-1))^2)((1/64) (((3η-4(Sqrt[1-(c^2)])ξ-3c))^2)(t^4)+(1/64)(32(c^2)(ξ^2)+32(ξ^2)−64c(Sqrt[1−(c^2)])ξ−18(η^2)+36c η−34(c^2)+16)(t^2)+(1/64)((((3η+4(Sqrt[1−(c^2)])ξ+5c))^2)−64));
ϕ41[t_,c_,ξ_,η_]=(Sqrt[ψ41[t,c,ξ,η]+1])-1;
ξ41i[c_]=((c(1-(c^2))+(((1-c))^2)(Sqrt[3+4c+(c^2)]))/(2(Sqrt[1-(c^2)])));
η41i[c_]=(1/3)(8-7c+2(c^3)-2(((1-c))^2)(Sqrt[3+4c+(c^2)]));
Clear[β1];
β1[c_]=-2 (4 (c^8)+4 (4+(Sqrt[2])) (c^6)-(1+6 (Sqrt[2])) (c^4)+2 (c^2)+3+2 (Sqrt[2]));
β0[u_,c_]=36 (3-2 (Sqrt[2])) (c^9)+16 (3 (Sqrt[2])-5) (c^8) u+ (329-198 (Sqrt[2])+(12-8 (Sqrt[2])) (u^2))(c^7)+(142 (Sqrt[2])-253) (c^6) u+ (169-198 (Sqrt[2])+(55-34 (Sqrt[2])) (u^2))(c^5)+(174 (Sqrt[2])-51+(2 (Sqrt[2])-3) (u^2))(c^4) u + (4 (43+9 (Sqrt[2]))-5 (6 (Sqrt[2])-7) (u^2))(c^3)-(16 (7+3 (Sqrt[2])) u+(3-2 (Sqrt[2])) (u^3))(c^2) +2 (23+16 (Sqrt[2])) u-4 c (10+9 (Sqrt[2])+(Sqrt[2]) (u^2));
u41o[c_]=If[c==0,2 (Sqrt[(1/7) (-1+2 (Sqrt[2]))]),-((4 (Sqrt[249+176 (Sqrt[2])-(217+152 (Sqrt[2])) (c^2)+2 (c^4)]))/(3 c))Cos[(1/3)ArcCos[(((5555+3928 (Sqrt[2])-3 (2423+1713 (Sqrt[2])) (c^2)+3 (478+337 (Sqrt[2])) (c^4)+2 (Sqrt[2]) (c^6)))/(((249+176 (Sqrt[2])-(217+152 (Sqrt[2])) (c^2)+2 (c^4)))^(3/2)))]-((4π)/3)]+((-22-16 (Sqrt[2])+15 (c^2)+4 (Sqrt[2]) (c^2))/(3 c))];
ξ41o[c_]=((-β0[u41o[c],c]-β1[c]* u41o[c])/(8β1[c](Sqrt[1-(c^2)])));
η41o[c_]=((-β0[u41o[c],c]+β1[c]* u41o[c])/(6β1[c]));

Optimal quadratic (G^0) approximant

angles={(π/2),(π/3),(π/4),(π/6),(π/8),(π/12)};
Nerror=3;
(Subscript[di, 20])={};
(Subscript[do, 20])={};
(Subscript[dd, 20])={};
For[i=1,i<=Length[angles],i++,
cc=Cos[angles[[i]]];
AppendTo[(Subscript[di, 20]),{N[ξ20i[cc]],ScientificForm[N[-ϕ20[((Sqrt[2])/2),cc,ξ20i[cc]]],Nerror]}];
If[cc==0,AppendTo[(Subscript[do, 20]),{"no approximant", "--"}],AppendTo[(Subscript[do, 20]),{N[ξ20o[cc]],ScientificForm[N[ϕ20[0,cc,ξ20o[cc]]],Nerror]}]];
ξξ=ξ/.NSolve[ϕ20[0,cc,ξ]+ϕ20[((Sqrt[(ξ^2)+(cc^2)-2])/(ξ-cc)),cc,ξ]==0&&2-cc<ξ<(cc^2)-3cc+3,ξ][[1]];
AppendTo[(Subscript[dd, 20]),{ξξ,ScientificForm[N[ϕ20[0,cc,ξξ]],Nerror]}]
]
Grid[Join[{{φ,"(SuperStar[ξ])","error","(ξ^∧)","error","(ξ^∨)","error"}},Table[Flatten[{angles[[i]],(Subscript[dd, 20])[[i]],(Subscript[do, 20])[[i]],(Subscript[di, 20])[[i]]}],{i,Length[angles]}]],Frame->All]

Optimal cubic (G^1) approximant

angles={(π/2),(π/3),(π/4),(π/6),(π/8),(π/12)};
Nerror=3;
(Subscript[di, 31])={};
(Subscript[do, 31])={};
(Subscript[dd, 31])={};
For[i=1,i<=Length[angles],i++,
cc=Cos[angles[[i]]];
AppendTo[(Subscript[di, 31]),{N[ξ31i[cc]],ScientificForm[N[-ϕ31[0,cc,ξ31i[cc]]],Nerror]}];
AppendTo[(Subscript[do, 31]),{N[ξ31o[cc]],ScientificForm[N[ϕ31[(1/(Sqrt[3])),cc,ξ31o[cc]]],Nerror]}];
ξξ=ξ/.FindRoot[D[ϕ31[t,cc,ξ],t]==0&&ϕ31[0,cc,ξ]+ϕ31[t,cc,ξ]==0,{ξ,ξ31o[cc]},{t,0.7}];
AppendTo[(Subscript[dd, 31]),{ξξ,ScientificForm[-N[ϕ31[0,cc,ξξ]],Nerror]}]
]
Grid[Join[{{φ,"(SuperStar[ξ])","error","(ξ^∧)","error","(ξ^∨)","error"}},Table[Flatten[{angles[[i]],(Subscript[dd, 31])[[i]],(Subscript[do, 31])[[i]],(Subscript[di, 31])[[i]]}],{i,Length[angles]}]],Frame->All]

Optimal quartic (G^2) approximant

angles={(π/2),(π/3),(π/4),(π/6),(π/8),(π/12)};
Nerror=3;
(Subscript[di, 42])={{N[ξ42i[0]],ScientificForm[N[Limit[-ϕ42[(1/2),c,ξ42i[c]],c->0]],Nerror]}};
(Subscript[do, 42])={{N[ξ42o[0]],ScientificForm[N[Limit[ϕ42[0,c,ξ42o[c]],c->0]],Nerror]}};
(Subscript[dd, 42])={{"-",ScientificForm[0.0006952749883544218`,Nerror]}};
For[i=2,i<=Length[angles],i++,
cc=Cos[angles[[i]]];
AppendTo[(Subscript[di, 42]),{N[ξ42i[cc]],ScientificForm[N[-ϕ42[(1/2),cc,ξ42i[cc]]],Nerror]}];
ξξ=ξ/.NSolve[((48(Sqrt[1-(cc^2)])(ξ^3))/cc)+48(ξ^2)-12(Sqrt[1-(cc^2)])((3/cc)+cc)ξ+12(1-(cc^2))==0&&(1/(6(Sqrt[1-(cc^2)])))(-2cc+(Sqrt[9-2(cc^2)-3(cc^4)]))<ξ,ξ][[1]];
AppendTo[(Subscript[do, 42]),{N[ξξ],ScientificForm[N[ϕ42[0,cc,ξξ]],Nerror]}];
ξξ=ξ/.FindRoot[D[ϕ42[t,cc,ξ],t]==0&&ϕ42[0,cc,ξ]+ϕ42[t,cc,ξ]==0,{ξ,ξξ},{t,0.7}];
AppendTo[(Subscript[dd, 42]),{ξξ,ScientificForm[N[ϕ42[0,cc,ξξ]],Nerror]}]
]
Grid[Join[{{φ,"(SuperStar[ξ])","error","(ξ^∧)","error","(ξ^∨)","error"}},Table[Flatten[{angles[[i]],(Subscript[dd, 42])[[i]],(Subscript[do, 42])[[i]],(Subscript[di, 42])[[i]]}],{i,Length[angles]}]],Frame->All]

Optimal cubic (G^0) approximant

angles={(π/2),(π/3),(π/4),(π/6),(π/8),(π/12)};
Nerror=3;
(Subscript[di, 30])={};
(Subscript[do, 30])={};
(Subscript[dd, 30])={};
For[i=1,i<=Length[angles],i++,
cc=Cos[angles[[i]]];
{ξξi,ηηi}={ξ,η}/.FindRoot[(D[ϕ30[t,cc,ξ,η],t]/.t->(1/2))==0&&ϕ30[(1/2),cc,ξ,η]==0,{ξ,ξ30o[cc]},{η,η30o[cc]}];
AppendTo[(Subscript[di, 30]),{ξξi,ηηi,ScientificForm[N[-ϕ30[0,cc,ξξi,ηηi]],Nerror]}];
AppendTo[(Subscript[do, 30]),{N[ξ30o[cc]],N[η30o[cc]],ScientificForm[N[ϕ30[(1/(Sqrt[3])),cc,ξ30o[cc],η30o[cc]]],Nerror]}];
{ξξ,ηη}={ξ,η}/.FindRoot[D[ϕ30[t,cc,ξ,η],t]==0&&ϕ30[0,cc,ξ,η]==ϕ30[t,cc,ξ,η]&&D[ϕ30[s,cc,ξ,η],s]==0&&ϕ30[t,cc,ξ,η]+ϕ30[s,cc,ξ,η]==0,{{ξ,ξ30o[cc]},{η,η30o[cc]},{s,0.6},{t,0.9}}];
AppendTo[(Subscript[dd, 30]),{ξξ,ηη,ScientificForm[-N[ϕ30[0,cc,ξξ,ηη]],Nerror]}]
]
Grid[Join[{{φ,"(SuperStar[ξ])","(SuperStar[η])","error","(ξ^∧)","(η^∧)","error","(ξ^∨)","(η^∨)","error"}},Table[Flatten[{angles[[i]],(Subscript[dd, 30])[[i]],(Subscript[do, 30])[[i]],(Subscript[di, 30])[[i]]}],{i,Length[angles]}]],Frame->All]

Optimal quartic (G^1) approximant

angles={(π/2),(π/3),(π/4),(π/6),(π/8),(π/12)};
Nerror=3;
(Subscript[di, 41])={};
(Subscript[do, 41])={};
(Subscript[dd, 41])={};
For[i=1,i<=Length[angles],i++,
cc=N[Cos[angles[[i]]]];
{ξξ,ηη}={ξ,η}/.FindRoot[D[ϕ41[t,cc,ξ,η],t]==0&&ϕ41[0,cc,ξ,η]==ϕ41[t,cc,ξ,η]&&D[ϕ41[s,cc,ξ,η],s]==0&&ϕ41[t,cc,ξ,η]+ϕ41[s,cc,ξ,η]==0,{{ξ,ξ41o[cc]},{η,η41o[cc]},{s,0.4},{t,0.8}}];
AppendTo[(Subscript[di, 41]),{ξ41i[cc],η41i[cc],ScientificForm[N[-ϕ41[(1/2),cc,ξ41i[cc],η41i[cc]]],Nerror]}];
AppendTo[(Subscript[do, 41]),{ξ41o[cc],η41o[cc],ScientificForm[N[ϕ41[0,cc,ξ41o[cc],η41o[cc]]],Nerror]}];
AppendTo[(Subscript[dd, 41]),{ξξ,ηη,ScientificForm[N[ϕ41[0,cc,ξξ,ηη]],Nerror]}]
]
Grid[Join[{{φ,"(SuperStar[ξ])","(SuperStar[η])","error","(ξ^∧)","(η^∧)","error","(ξ^∨)","(η^∨)","error"}},Table[Flatten[{angles[[i]],(Subscript[dd, 41])[[i]],(Subscript[do, 41])[[i]],(Subscript[di, 41])[[i]]}],{i,Length[angles]}]],Frame->All]